Tag Archives: programming

Arduino I2C Scanner

What is the I2C address?! Scanner please.

Do I need such scanner? Sooner or later, everyone stuck on some I2C device – unknown address. For example, on OLED display, there is jumper (SMD resistor with “000” – zero Ohms), and next to it: “IIC address eslect”, and two options, soldered at first one: 0x78, and can be selected another one by removing this resistor and soldering at second place: 0x7A. But, after opening example code for this OLED display, it does not works. Why?! Because it has address of 0x3C, not 0x78 as it is designated. So, here is simple sketch I found somewhere. Well known and simple sketch, but very useful:

// --------------------------------------
//    i2c_scanner
//
//    Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
//    Version 2, Juni 2012, Using Arduino 1.0.1
//    Adapted to be as simple as possible by Arduino.cc user Krodal
//    Version 3, Feb 26  2013
//    V3 by louarnold
//    Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
//    Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
//    Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
//
//
//    This sketch tests the standard 7-bit addresses
//    Devices with higher bit address might not be seen properly.
//
 
#include <Wire.h>
 
 
void setup()
{
  Wire.begin();
 
  Serial.begin(115200);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}
 
 
void loop()
{
  byte error, address;
  int nDevices;
 
  Serial.println("Scanning...");
 
  nDevices = 0;
  for(address = 1; address < 127; address++ )
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
 
    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");
 
      nDevices++;
    }
    else if (error==4)
    {
      Serial.print("Unknow error at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");
 
  delay(5000);           // wait 5 seconds for next scan
}

You may use :

Serial.begin(9600);
// instead
Serial.begin(115200); 
// it is up to you which speed you will use for serial

Most of the default examples uses 9600 bits per second, but sometimes I need it faster, so I made it “115200”.  If you have problem with your serial port (USB cable to your Arduino), then lower speed, it is up to you. Just be sure to select the same speed at Serial Monitor, bottom right corner. Else it will not work.

Wiring

Instead making wiring diagram, I will just tell you that SCL and SDA of the device in question goes to SCL and SDA on your favorite  Arduino board.  Usually with numbers 4 and 5; SCL (serial clock) to pin A5 (or ADC5, or pin number 28), and SDA (seral data) to pin A4 (or ADC4, or pin number 27). Do not forget to power your device with appropriate voltage and connect ground wire. Usually it is 5V, but there may be exceptions.

It will give you info every five seconds, something like this:

scanner

Arduino altimeter

Altimeter: Another problem with losing data during lost signal:

Altimeter sketch, Tried to change library from VirtualWire.h to RadioHead.h, but memory on Arduino nano is already too much populated, working memory for variables. So… Don’t know what to do… OLED display take 1024 bytes (1 kB), maybe I should to consider different display?

Altimeter programming problemsaltimeter

Altimeter: some outdoor test is done with one big mistake…

This video is made before utilizing “second order temperature compensation” in sketch of the transmitter. It looks complicated, but it turns out that is actually simple to apply (or I become somewhat good in programming). 😀 What happens is that I set zero indoor where temperature is close to 20°C, but outdoor in early morning was just 7°C, which gives me error of about -6 meters. Now things are better, error is still present but no more than say – 3 meters. BUT (!), now this error is within ballpark of maximum -3 meters error if temperature changes dramatically, which in most situations is not the case. Problem may occur during winter time, when someone want to fly briefly, and bring outside “warm” quad with sensor at say 20°C, then begins to fly – when set zero on ground, fly, and back, on ground should be again zero. For this reason, give quad and sensor some time to accommodate to whatsoever temperature outdoor is. Sensor is temperature dependent, and between 20°C and maximum operating temperature of 85°C it has pretty linear reading. The problem begins below 20°C, and exponentially rise with lowering temperature. But, since we are not interested in correct atmospheric pressure, but rather correct measured altitude, such error of -3 meters (which is about 0.5 mb, or 0.5 hPa), is next to nothing if quad fly very high AND (!) in meanwhile temperatures drops drastically. Down below is sketch for Attiny85, which is now corrected with added additional math. In the worst case of temperature drop, error is no more than -16 meters at temperatures between -15°C and -40°C DIFFERENCE (!) between starting temperature and temperatured during flight. And, I doubt that anyone has actual will to fly on such cold and freezing butt temperature. 😀

Altimeter: transmitter under 3 grams! (2.75 g with antenna)

altimeter

On this ‘remote’ altimeter, still need to add ISP connector with 6 wires for re-programming firmware. Just in case that something need to be changed. Else, it is under 3 grams, but as ‘features’ growing, it will be slightly above 3 grams. For example, this 1/4 lambda antenna is okay, but full dipole (1/2 lambda) is better for more range. Just need to finish receiver end, post it on this page, and test maximum possible range. I am hoping for 1 km or more, but will see. Also, not sure how it will looks like on the quadcopter. For rockets, there will be different version – one without transmitter, just recording max altitude in EEPROM, then red with some base station, but that is future plan. Or, maybe I will find some good and lightweight LCD display… don’t know… For quadcopters, it is good to monitor altitude dynamicaly – in flight, but for rockets… eh, it goes hight as it goes – no way to monitor it in real time.

Arduino Altimeter – first steps are done

Altimeter – Beta version works on 433 MHz, base station should be pressed “zero” to set zero of the vehicle (airplane, quadcopter…), and then it will calculate altitude by receiving data from vehicle to the base station. So far, I have some problem with OLED display and it’s library: it uses too much memory and some instability occurs when it is out of range and not used for longer period. Just need to see what may be done…

Altimeter

Download (PDF, 98KB)

Working day and night… not only this project, but other things as well. Just some short video:

On this video, pressure sensor MS5611-01BA01 is used. By clicking on this link, you will get datasheet if you are interested.

Another PDF file MS5611-01BA03, much detailed, where at pages 17, 18 and 19 – diagrams showing error in pressure and temperature measurements without applying “Second order temperature compensation”, where sensor below 20°C increasing interpreting pressure reading exponentially as temperature goes really low. This math correcting it as much as possible. Still some error remains, but with peak of about 1.8 mBar at temperatures between -15°C and -40°C. Without this, additional math, error at such temperatures are up to 28 mBar at -40°C. At some “normal” local atmospheric pressures of say 1000 mBar, error of 1 mBar equals 8.426 meters. As pressure goes down, this error goes down. So at very high altitude, where temperatures are low – error becomes less important. I will be more worried about LiPo battery, than about sensor.

Another changes

Changed way of displaying Actual altitude, and Maximum altitude reached, shown as A: and M: respectively. Both in feet and meters.

altimeter

And got idea about barometric pressure (for altitude calculation), humidity and temperature of the base station. Later will be added another barometric sensor in the case of rapid change in weather, as is case past few days prior to rain. This second sensor together with humidity and temperature will make it almost complete meteorologic station, mobile one. Just missing wind speed, and few other parameters, but so far – it looks much better and more “rich” than before. 😀 To read meteo-data, just switch into second position, while altimeter continues to measure altitude and “remember” maximum reached. MaxAlt is done by simple code:

if (maxAltitude<=altitude) {maxAltitude=altitude;}

altimeter

I wish to have better and bigger display in order to show all data at once instead changing “pages” on OLED, but here it is, what it is… New Nextion display ordered, just waiting to arrive.

First codes for TX, test phase

So far it works as a “Packet Radio” on 433 MHz, the ISM frequency. Transmitter and sensor + Attiny85 is chosen so that whole sending device will be under 3 grams – good for any vehicles. Unfortunately, it can’t work as altimeter not as vario + altimeter as planed. The main problem is in receiver side; if I combine relative slow transmission, some 24 packets maximum, tone sounds crazy and has delay. So, later version of the Arduino altimeter will has switch to chose altimeter or vario with the same circuit. For now, I did only altimeter, everything else will be added later (for those who found this page before end of test or beta phase of developing).

Some errors corrected

In the example below, initial idea is used from Arduino Vario by Rolf R. Bakke. He made initial code in such way that pressure is with OSR (OverSampling Ratio) for pressure, which is 4096 , so that resulting RMS (Root Mean Square) is 0.012 mBar (the lower number – the more precision). But (!), because higher OSR requires longer conversion inside MS5611 sensor chip, this value requires delay of 9.04 ms (minimum 7.40 ms, typical value is 8.22 ms and maximum value is 9.04 ms), So, for sake of ‘safety margins’, he uses 10 ms delay for pressure reading, since ADC need this time in OSR mode 4096. But, he uses OSR for temperature of just 256, which is equivalent of RMS of 0.012 °C, which is okay for vario, but not for altimeter – numbers jumping up and down too much. He probably made this decision because vario should be very fast, and already present delay of 10 ms + 1 ms at another command, adding more delay may result in too slow vario to be useful for sailplanes or gliders. The more samples per second – the faster the response.

Vario is one thing, altimeter another

For this reason, I changed call function from “D2 = getData(0x50, 1);” to “D2 = getData(0x58, 10);”, which has RMS of 0.002 °C – much better temperature correction data (six time better temperature correction than in the case of OSR 256, which gives RMS of 0.012 °C), but ten times longer to read (instead 1 ms, it needs over 9 ms to complete oversampling). The same as above for pressure, I am using 10 ms for good measure to prevent error(s). Anyone who want to experiment, try change from 10 ms to 1 – terrible error occur, instead some ‘reasonable’ pressure of say 1010 mbar, there is nonsense, something like -2.5 mbar. ADC converter just can’t cope with that speed, and reading sensor ends in big, really big error.

Why then in Attiny85 code is 1000 instead 10 ms?!

This is mystery to me. I had no time to investigate, but I suspect that library ‘VirtualWire’ resulting in such strange thing. It is actually good to have tens of microseconds (!) instead of thousands, or 1 ms (1000 µs = 1 ms). Since this strange thing is there, anyone who want to change some delay should multiply wanted value by factor of 100 to get proper delay in milliseconds. For example ‘delay(1000)’ usually means 1 second, but in example below, it will be delayed just 10 ms. So, for whole second, it should be ‘delay(100000)’. There is some limit, where delay can’t be set to high value, but instead should be used ‘for/to/next’ loop for more delay, if needed. For example 12 seconds: “for (i=1;i<=12;i++) {delay(100000)}”. This will be delay of 1 second repeated 12 times – 12 seconds. But, this is out of scope for this altimeter.

// Altimeter code by Milan Karakaš 2016
// Revision 2 - some precission errors corrected
// Revision 3 - added "second order temperature compensation",
// which corrects pressure error when temperature goes below 20°C.
// 315 MHZ or 433 MHz ASK (OOK) transmitter
// MS5611 sensor - just altimeter for now 
// Vehicle ID or just ID - set as you wish
// WARNING!!! delay 1000 ms -> delay 100000, 
// or two zerros to add, or multiply by 100
// don't know why it happens, so 1 ms should be
// writen as 100, not 1 as usually...
// Note that this is still beta version, need testing!

#include <TinyWireM.h>
#include <VirtualWire.h>
#include <Average.h>

#define n 4 //define number of average 
// the biger number n, the longer pause between two transmissions
Average<long>ave(n);
unsigned int calibrationData[7];
unsigned long time = 0;
long pressure, D1, D2, dT, P, Pa, TEMP, T2;
int ddsAcc, volt;
int64_t OFF, OFF2, SENS, SENS2;
byte data[7]; //number of data in array - 1 byte fir ID and 4 bytes for pressure
byte ID=0x2A; //"Vehicle ID" - set different value for each vehicle, also on RX side "myTX=0x2A"
float vref=5.07;

void setup()
{
 TinyWireM.begin(); //begins to comunicate with pressure sensor
 vw_set_tx_pin(1);  //set pin 4 (physical pin 3) on Attiny 85
 vw_setup(4800);    // Bits per sec
 setupSensor();     //call function for setup of the MS5611 sensor
// pinMode(4,INPUT);  //voltage measurement input
//vw_set_ptt_pin(3);  //depends of type of the transmitter 
                    //some no needs this, so use LED instead :)
                    //is is better to disable this pin, because
                    //some boards as is USB version of Attiny85
                    //uses this pins for something else
}

void loop()
{

for (int i=0;i<n;i++) //
  {
 getPressure();
 ave.push(P);
  }
Pa=(ave.mean()); //mean value of ave number (for example ave(10) is ten samples averaged)
volt=((analogRead(2)*vref)/1024)*100;

data[0]=ID;     //sending ID to array
data[1] = Pa;          //split long into first byte
data[2] = (Pa >> 8);   //split long into second byte
data[3] = (Pa >> 16);  //split long into third byte
data[4] = (Pa >> 24);  //split long into fourth and last byte
data[5] = volt;
data[6] = (volt >>8);

vw_send(data,7);       //now sending ID and four bytes to the receiver
vw_wait_tx();          //waiting until transmitter ends whole packet
delay(1000);// WARNING!!! delay 1000 ms -> delay 100000, two zerros add, or multiply by 100
/*This delay should be changed together with "Vehicle ID" in the case that multiple users 
 * fly at the same time to avoid overlaping and too much interferences. Receiver side has
 * CRC error checking, and in the case of interferences, it will just drop wrong packet and
 * continue listening until valid packet(s) is/are received. ID is single byte, and can be 
 * anything from 0 to 255 or in hexadecimal from 0x00 to 0xFF. In this case above of 1 mS 
 * delay, together with averaging of 4 samples from the MS5611 sensor, it gives 5 packets 
 * per second at 4800 bits per second. Sufficiently good for "normal" flight of quadcopter.
 */
}

//subfunction to get pressure
long getPressure()
{
//long D1, D2, dT, P, T2;
//long TEMP;
//int64_t OFF, SENS;

D1 = getData(0x48, 1000);
D2 = getData(0x58, 1000);

dT = D2 - ((long)calibrationData[5] << 8);
TEMP = (2000 + (((int64_t)dT * (int64_t)calibrationData[6]) >> 23)); //temperature before second order compensation
if (TEMP<2000)  //if temperature of the sensor goes below 20°C, it activates "second order temperature compensation"
{
  T2=pow(dT,2)/2147483648;
  OFF2=5*pow((TEMP-2000),2)/2;
  SENS2=5*pow((TEMP-2000),2)/4;
  if (TEMP<-1500) //if temperature of the sensor goes even lower, below -15°C, then additional math is utilized
  {
    OFF2=OFF2+7*pow((TEMP+1500),2);
    SENS2=SENS2+11*pow((TEMP+1500),2)/2;
  }
}
else 
{
T2=0;
OFF2=0;
SENS2=0;
}
TEMP = ((2000 + (((int64_t)dT * (int64_t)calibrationData[6]) >> 23))-T2); //second order compensation included
OFF = (((unsigned long)calibrationData[2] << 16) + (((int64_t)calibrationData[4] * dT) >> 7)-OFF2); //second order compensation included
SENS = (((unsigned long)calibrationData[1] << 15) + (((int64_t)calibrationData[3] * dT) >> 8)-SENS2); //second order compensation included
P = (((D1 * SENS) >> 21) - OFF) >> 15; 
return P; //returns back into main loop data about pressure P
}

long getData(byte command, int del) //function to getting data from the sensor
{
long result = 0;
twiSendCommand(0x77, command);
delay(del);
twiSendCommand(0x77, 0x00);
TinyWireM.requestFrom(0x77, 3);
if(TinyWireM.available()!=3);  // serial print je bio ovdje

for (int i = 0; i <= 2; i++)
{
result = (result<<8) | TinyWireM.read(); //read
}
return result;
}

//lets setup darn sensor :)
void setupSensor()
{

twiSendCommand(0x77, 0x1e);
delay(1000); //timing important - 1 ms = 1 ms * 100

for (byte i = 1; i <=6; i++)
{
unsigned int low, high;

twiSendCommand(0x77, 0xa0 + i * 2);
TinyWireM.requestFrom(0x77, 2);
if(TinyWireM.available()!=2);// Serial.println("Error: calibration data not available"); */
high = TinyWireM.read();
low = TinyWireM.read(); //read
calibrationData[i] = high<<8 | low;
}
}

//twi, whatsoever this means
void twiSendCommand(byte address, byte command)
{
  TinyWireM.beginTransmission(address);
  TinyWireM.write(command); //write
  TinyWireM.endTransmission();
}

 

Base station

Base station has OLED display for now, because found only this one. Later will consider make various options; OLED, TFT, numeric LCD, graphic LCD…

Just need time… First code for base station is here (sorry, no diagram yet, working whole night – for those who found this page in the meanwhile)

EDITED, forgot to assign Arduino Pin 9 and Pin 10 to the button and switch.

It is used later in program, but somehow forgot to set it in setup() function. It is ‘pinMode(9,INPUT);’ , as well as ‘pinMode(10,INPUT);’, also internal pull-up resistor ‘digitalWrite(9,HIGH);’ and ‘digitalWrite(10,HIGH);’  :

// Altimeter code by Milan Karakaš 2016
// Revision 2 - some precission errors corrected
// Revision 3 - sorted OLED screen; first screen showing Actual Altitude
// and Maximum reached Altitude, second screen showing barometric pressure
// Humidity and temperature sensors showing humidity and temperature on 
// the base station - very important is to know humidity, because every 
// flying object 'float' better when humidity is low (!)

#include <VirtualWire.h>
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

#define DHTPIN 2
#define DHTTYPE DHT22
#define OLED_RESET 4
Adafruit_SSD1306 display(OLED_RESET);
#define degree_GLCD_HEIGHT 8
#define degree_GLCD_WIDTH 8
DHT dht(DHTPIN, DHTTYPE);
static const unsigned char PROGMEM degree_glcd_bmp[]=
{0x60, 0x90, 0x90, 0x60, 0x0,};
float altitude, maxAltitude,setpress,t,h;

uint8_t buf[7];
uint8_t buflen = 7;
long P;
byte ID, myTX=0x2A; //be sure that on your TX, the same ID "myTX is the same", here 0x2A hexacecmal
float volt;
float battOK=3.7; //minimum desired voltage for safe flight

void setup()
{
pinMode(9,INPUT); //this pin I forgot to include! Sorry people. 
digitalWrite(9,HIGH); //this one serves instead external 'pull-up' resistor - every time you have INPUT and provide HIGH to the output, it internally enable that resistor.
pinMode(10,INPUT); //also this one for switching display for various data sets.
digitalWrite(10,HIGH);//I think that one needs to, but actually this is switch, pin 10 goes to GND for one display option, or to +5V (or 3.3V) for another display option. Will turn pull-up resistor just in case.
display.begin(SSD1306_SWITCHCAPVCC, 0x3c);  // initialize with the I2C addr 0x3C (for the 128x32)
display.clearDisplay();
vw_set_rx_pin(7);
vw_setup(4800);
vw_rx_start();
dht.begin();
}

void loop()
{
  if (vw_get_message(buf,&buflen)) 
   {
     byte ID=buf[0];
   if (ID==myTX) 
   // if vehicle ID is wrong, it will just freeze last result, and do nothing
   // until "proper" connection is established, or proper ID is read - in the
   // case of more than one vehicle, each other will NOT listen (no 'crosstalk', 
   // so it will not showing wrong data - just vehicle which has proper ID
   {
     long P=((long)buf[1])+((long)buf[2]<<8)+((long)buf[3]<<16)+((long)buf[4]<<24);
     float volt=((buf[5])+(buf[6]<<8))/(float)100;
     if (volt<battOK) 
      {
      tone(3,800); 
      delay(50);
      noTone(3);
      }
     int line = (64-((volt-3.3)*71));
     altitude=145366.45*(1-pow(((P/(float)100)/(setpress/(float)100)),0.190284));
    
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius
  float t = dht.readTemperature();

     if (maxAltitude<=altitude) {maxAltitude=altitude;}

     if (digitalRead(9)==1)
      { delay(100);
      //by pressing button, Actual Altitude, and Maximum or Memorized Altitude
      //is set to zero as well
      //In the case of some major error, please press reset button on your Arduino
       setpress=P; 
       maxAltitude=altitude;
      }

     if (digitalRead(10)==1)
      {
        //write results, A: stands for Actual Altitude, 
        //M: stands for Maximum or Memorized Altitude
        display.clearDisplay();
        display.setTextSize(2);
        display.setTextColor(1);
        display.setCursor(0,0);
        display.print("A:");
        display.print(altitude,1);
        display.setCursor(0,16);
        display.setTextSize(2);
        display.print("A:");
        display.print(altitude*0.3048,1);
        display.setTextSize(2);
        display.setCursor(0,32);
        display.print("M:");
        display.println(maxAltitude,1);
        display.print("M:");
        display.print(maxAltitude*0.3048,1);
        //write designations as is feet and meters (ft, m)
        display.setTextSize(1);
        display.setCursor(113,3);
        display.println("ft");
        display.setCursor(118,19);
        display.setTextSize(1);
        display.print("m");
        display.setCursor(113,36);
        display.print("ft");
        display.setCursor(118,51);
        display.print("m");
        display.drawLine(127,64,127,line,1);
        display.display();
      }
      else 
      {
        //if switch is in different postion, show Actual Pressure,
        //humidity and temperature for weather station + battery status
        display.clearDisplay();
        display.setTextSize(2);
        display.setTextColor(1);
        display.setCursor(0,0);
        display.print("P:");
        display.print((float)P/100,2);
        display.setCursor(0,48);
        display.print("Bat: ");
        display.print((float)volt,2);

        display.setTextSize(2);
        display.setCursor(0,16);
        display.print("H:  ");
        display.println(h,2);
        display.print("T:  ");
        display.print(t,2);
        //lets make some symbols
        display.setTextSize(1);
        display.setCursor(108,03);
        display.println(" mb");
        display.setCursor(117,18);
        display.print("%");
        //Bitmap for symbol for degrees 
        display.drawBitmap(110,31,degree_glcd_bmp,8,8,1);
        display.setCursor(115,31);
        display.setTextSize(2);
        display.print("C");
        display.setCursor(115,48);
        display.print("V");
                display.setCursor(118,51);
        display.print("m");
        display.drawLine(127,64,127,line,1);
        display.display();
      }
   }
   // if this point is reached, probably ID is wrong, and it will back into loop again
   //else if (ID!=myTX) {tone(3,3000);delay(50);noTone(3);} 
   //do not apply code above - too loud, headache :D just leave it "open" to back into loop
   
   }

 }

 

The same MS5611 sensor is used in Arduino variometer. And it is cheaper than ever on Banggood.com

This is all for now

Come back soon, will be updated… Escpecially diagram and videos… Spring time requires hard work in my backyard, but also I did now and then some job for money, and this is main reason of delay of everything.